Changed name capitalization

BoxBoy/BoxBoy.gd

@@ -0,0 +1,71 @@
+class_name BoxBoy extends CharacterBody2D
+
+@onready var _sprite = $AnimatedSprite2D
+
+const MOVE_FORCE: int = 300
+const JUMP_FORCE: int = 500 #about 4 tiles
+
+const GRAVITY_RISING: int = 15
+const GRAVITY_FALLING: int = 30
+
+#bouncy platform
+const BOUNCE_FORCE: int = -820 #about 10 tiles
+var just_bounced: bool = false #allow max bounce height (i.e. ignore jump input)
+
+#limits
+const MAX_MOVE_SPEED: int = 300
+const MAX_FALL_SPEED: int = 500
+
+#boilerplate
+func _ready():
+	_sprite.play("idle", 1)
+
+#movement
+func _physics_process(_delta) -> void:
+	#jump input
+	if is_on_floor() and Input.is_action_just_pressed("input_jump"):
+		velocity.y -= JUMP_FORCE
+	
+	#normally, fall faster than you rise
+	elif is_rising() and (Input.is_action_pressed("input_jump") or just_bounced):
+		velocity.y += GRAVITY_RISING
+	else:
+		velocity.y += GRAVITY_FALLING
+		just_bounced = false
+	
+	#sideways movement
+	var move_dir = Input.get_axis("input_left", "input_right")
+	
+	if move_dir:
+		_sprite.flip_h = move_dir < 0 #fancy HD 4K graphics
+		velocity.x += MOVE_FORCE * move_dir
+	
+	#no input, slow down
+	elif velocity.x != 0:
+		velocity.x = log(abs(velocity.x)) * sign(velocity.x)
+	
+	#terminal velocity (in all directions)
+	if is_falling() and velocity.y > MAX_FALL_SPEED:
+		velocity.y = MAX_FALL_SPEED
+	if abs(velocity.x) > MAX_MOVE_SPEED:
+		velocity.x = MAX_MOVE_SPEED * sign(velocity.x)
+	
+	#do the thing
+	move_and_slide()
+
+#animation stuff
+func _on_animation_finished() -> void:
+	if randf() < 0.2:
+		_sprite.play("idle_glance", 2)
+	else:
+		_sprite.play("idle", 2)
+
+#utils
+#func is_airborne() -> bool: return !is_on_floor()
+func is_rising() -> bool: return velocity.y < 0
+func is_falling() -> bool: return velocity.y >= 0
+
+#external actions
+func apply_bounce() -> void:
+	velocity.y = BOUNCE_FORCE
+	just_bounced = true